Διαφορικός Λογισμός

Πρώτες μερικές παράγωγοι και προσδιορισμός τιμών τους σε σημείο.

Clear["Global`*"]
f[x_, y_] := 1/(x^2 + y^2 + 1);
fDx[x_, y_] := Evaluate[D[f[x, y], x]]
fDy[x_, y_] := Evaluate[D[f[x, y], y]]
fDx[x, y]
\[-\frac{2 x}{{(1+x^{2}+y^{2})}^{2}}\]
fDx[2,3]
\[-\frac{1}{49}\]

Επίσης:

Derivative[1, 0][f][2, 3]
\[-\frac{1}{49}\]
Derivative[0, 1][f][2,   3]
\[-\frac{3}{98}\]

Ανώτερες μερικές παράγωγοι και προσδιορισμός τιμών τους σε σημείο.

fxx[x_, y_] := Evaluate[D[f[x, y], {x, 2}]]
fxy[x_, y_] := Evaluate[D[f[x, y], x, y]]

Έχουμε:

fxx[x, y]
fxy[x, y]
\[\frac{8 (x^{2})}{{(1+x^{2}+y^{2})}^{3}}-\frac{2}{{(1+x^{2}+y^{2})}^{2}}\]
\[\frac{8 x y}{{(1+x^{2}+y^{2})}^{3}}\]

Επίσης:

Derivative[2, 0][f][2,   3]
Derivative[1, 1][f][2, 3]
\[\frac{1}{686}\]
\[\frac{6}{343}\]

Ανάδελτα - Εσσιανή

gradient[x_, y_] := Evaluate[D[f[x, y], {{x, y}}]]
MatrixForm[gradient[x, y]]
\[\begin{pmatrix} -\frac{2 x}{{(1+x^{2}+y^{2})}^{2}} \\ -\frac{2 y}{{(1+x^{2}+y^{2})}^{2}} \end{pmatrix}\]
hessian[x_, y_] := Evaluate[D[f[x, y], {{x, y}}, {{x, y}}]]
hessian[x,y]//MatrixForm
\[\begin{pmatrix} \frac{8 (x^{2})}{{(1+x^{2}+y^{2})}^{3}}-\frac{2}{{(1+x^{2}+y^{2})}^{2}} & \frac{8 x y}{{(1+x^{2}+y^{2})}^{3}} \\ \frac{8 x y}{{(1+x^{2}+y^{2})}^{3}} & \frac{8 (y^{2})}{{(1+x^{2}+y^{2})}^{3}}-\frac{2}{{(1+x^{2}+y^{2})}^{2}} \end{pmatrix}\]

Ακρότατα

Αυτόματα

Συναρτήσεις μίας μεταβλητής

Clear["Global`*"]
f[x_] := 36 x^2 - 20 x^3 + 3 x^4
Plot[f[x], {x, -2, 4}]
-2 0 2 4 0 50 100 
FindMinimum[f[x], {x, 2.5, 4}]
FindMaximum[f[x], {x, 1, 2.5}]
\({27.`,{x\to 2.9999999578802803`}}\)
\({31.99999999999997`,{x\to 1.9999999947597802`}}\)
Minimize[f[x], 2.5 <= x <= 4, {x}]
Maximize[f[x], 1 <= x <= 2.5, {x}]
\({27.000000591187302`,{x\to 3.0001812138213357`}}\)
\({31.999998995032726`,{x\to 1.9997106227398245`}}\)
NMinimize[f[x], 2.5 <= x <= 4, {x}]
NMaximize[f[x], 1 <= x <= 2.5, {x}]
\({27.000000591187302`,{x\to 3.0001812138213357`}}\)
\({31.999998995032705`,{x\to 1.9997106227398216`}}\)

Συναρτήσεις πολλών μεταβλητών

Clear["Global`*"]
f[x_, y_] := x y Exp[-x^2 - y^2]
Minimize[f[x, y], {-3 <= x <= 3, -3 <= y <= 3}, {x, y}]
FindMinimum[{f[x, y], -3 <= x <= 3 && -3 <= y <= 3}, {x, y}]
\[{-\frac{1}{2 E},{x\to -\frac{1}{\sqrt{2}},y\to \frac{1}{\sqrt{2}}}}\]
\[{2.537835848777809`*^-7,{x\to 2.949376242950452`,y\to 2.9407881723893965`}}\]

Κατεύθυνση ανάδελτα

Clear["Global`*"]
f[x_, y_] := 1/(x^2 + y^2 + 1);
xmin = -2;
xmax = 2;
ymin = -2;
ymax = 2;
Plot3D[f[x, y], {x, xmin, xmax}, {y, ymin, ymax}, 
 MeshFunctions -> {#3 &} , MeshStyle -> {Gray}, 
 AxesLabel -> Automatic, ClippingStyle -> None, 
 ColorFunction -> "DarkRainbow", PlotRange -> All, PlotPoints -> 50]
3D Plot
fDx[x_, y_] := Evaluate[D[f[x, y], x]]
fDy[x_, y_] := Evaluate[D[f[x, y], y]]

Οι μερικές παράγωγοι είναι:

fDx[x, y]
fDy[x, y]
\[-\frac{2 x}{{(1+x^{2}+y^{2})}^{2}}\]
\[-\frac{2 y}{{(1+x^{2}+y^{2})}^{2}}\]

Και το ανάδελτα:

gradient[x_, y_] := Evaluate[D[f[x, y], {{x, y}}]];
MatrixForm[gradient[x, y]]
\[\begin{pmatrix} -\frac{2 x}{{(1+x^{2}+y^{2})}^{2}} \\ -\frac{2 y}{{(1+x^{2}+y^{2})}^{2}} \end{pmatrix}\]

Μηδενισμός ανάδελτα στο:

systemD = Solve[{fDx[x, y] == 0, fDy[x, y] == 0}, {x, y}];
 {x, y} /. systemD
{{0,0}}
StreamPlot[gradient[x, y], {x, xmin, xmax}, {y, ymin, ymax}, PlotLegends -> Automatic]
-2 -1 0 1 2 -2 -1 0 1 2
0.05 0.1 0.15 0.2 0.25 0.3 0.35 0.4 0.45 0.5 0.55 0.6 0.65

Κριτήρια Εσσιανής

Clear["Global`*"]
min0 = -1;
max0 = 4;
f[x1_, x2_] := x1 x2^3 - 3 x1 x2^2 + x2 x1^3 - 3 x2 x1^2
Plot3D[f[x, y], {x, min0, max0}, {y, min0, max0}, 
 MeshFunctions -> {#3 &}, MeshStyle -> {Gray}, 
 AxesLabel -> Automatic, ClippingStyle -> None, 
 ColorFunction -> "Rainbow", PlotPoints -> 50, 
 PlotLegends -> Automatic]
3D Plot -30 -25 -20 -15 -10 -5 0 5 10 15

Εύρεση κρίσιμων σημείων

fDx[x_, y_] := Evaluate[D[f[x, y], x]]
fDy[x_, y_] := Evaluate[D[f[x, y], y]]
systemD = Solve[{fDx[x, y] == 0, fDy[x, y] == 0}, {x, y}] // N
\[{{x\to 0.`,y\to 0.`},{x\to 0.`,y\to 3.`},{x\to 2.25`,y\to 2.25`},{x\to -0.31066017177982136`,y\to 1.8106601717798212`},{x\to 1.8106601717798212`,y\to -0.31066017177982136`},{x\to 0.`,y\to 0.`},{x\to 3.`,y\to 0.`}}\]
fDx2[x_, y_] := Evaluate[D[f[x, y], {x, 2}]]
(*Αν θέλουμε απλά την ορίζουσα της Εσσιανής, γράφουμε*)
detHessian[x_, y_] := 
 Evaluate[D[f[x, y], {x, 2}]*D[f[x, y], {y, 2}] - D[f[x, y], x, y]^2]
fDx2[x, y] /. systemD // N
detHessian[x, y] /. systemD // N
{0.`,-18.`,16.875`,-14.238961030678928`,-1.5110389693210728`,0.`,0.`}
{0.`,-81.`,273.375`,20.25`,20.25000000000001`,0.`,-81.`}

Έτσι:
- Για το ζεύγος (0,0) δεν μπορούμε ν' αποφανθούμε, αφού Η=0.
- Τα ζεύγη (0,3) και (3,0) είναι σαγματικά, αφού Η<0.
- Το ζεύγος (2.25, 2.25) είναι ελάχιστο, αφού Η>0 και $\partial_{xx} f(2.25,2.25)>0$.
- Τα ζεύγη (-0.31066, 1.81066) και (1.81066, -0.31066) είναι μέγιστα, αφού Η>0 και $\partial_{xx} f(x_ 0, y_ 0)<0$.

Μέγιστο

Clear["Global`*"]
fDx[x_, y_] := Evaluate[D[f[x, y], x]]
fDy[x_, y_] := Evaluate[D[f[x, y], y]]
f[x_, y_] := 1/(x^2 + y^2 + 1);
systemD = Solve[{fDx[x, y] == 0, fDy[x, y] == 0}, {x, y}];
Plot3D[f[x, y], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3 &} , 
 MeshStyle -> {Gray}, AxesLabel -> Automatic, ClippingStyle -> None, 
 ColorFunction -> "DarkRainbow", PlotRange -> All, PlotPoints -> 50]
3D Plot
hessian[x_, y_] := Evaluate[D[f[x, y], {{x, y}}, {{x, y}}]]

Η Εσσιανή είναι:

MatrixForm[hessian[x, y]]
\[\begin{pmatrix} \frac{8 (x^{2})}{{(1+x^{2}+y^{2})}^{3}}-\frac{2}{{(1+x^{2}+y^{2})}^{2}} & \frac{8 x y}{{(1+x^{2}+y^{2})}^{3}} \\ \frac{8 x y}{{(1+x^{2}+y^{2})}^{3}} & \frac{8 (y^{2})}{{(1+x^{2}+y^{2})}^{3}}-\frac{2}{{(1+x^{2}+y^{2})}^{2}} \end{pmatrix}\]

Και η ορίζουσά της:

Det[hessian[x, y]]
\[-\frac{16 (x^{2})}{{(1+x^{2}+y^{2})}^{5}}-\frac{16 (y^{2})}{{(1+x^{2}+y^{2})}^{5}}+\frac{4}{{(1+x^{2}+y^{2})}^{4}}\]

Επίσης $\partial f(0,0)=$

fDx2[x_, y_] := Evaluate[D[f[x, y], {x, 2}]]
fDx2[x, y]/. systemD
{-2}

Επίσης τιμή της ορίζουσας της εσσιανής στη θέση ισορροπίας \
είναι:

Det[hessian[x, y]] /. systemD
{4}

Επομένως έχουμε Μέγιστο.

Ελάχιστο

Clear["Global`*"]
fDx[x_, y_] := Evaluate[D[f[x, y], x]]
fDy[x_, y_] := Evaluate[D[f[x, y], y]]
f[x_, y_] := -(1/(x^2 + y^2 + 1));
systemD = Solve[{fDx[x, y] == 0, fDy[x, y] == 0}, {x, y}];
Plot3D[f[x, y], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3 &} , 
 MeshStyle -> {Gray}, AxesLabel -> Automatic, ClippingStyle -> None, 
 ColorFunction -> "DarkRainbow", PlotRange -> All, PlotPoints -> 50]
3D Plot
hessian[x_, y_] := Evaluate[D[f[x, y], {{x, y}}, {{x, y}}]]

Η Εσσιανή είναι:

MatrixForm[hessian[x,y]]
\[\begin{pmatrix} -\frac{8 (x^{2})}{{(1+x^{2}+y^{2})}^{3}}+\frac{2}{{(1+x^{2}+y^{2})}^{2}} & -\frac{8 x y}{{(1+x^{2}+y^{2})}^{3}} \\ -\frac{8 x y}{{(1+x^{2}+y^{2})}^{3}} & -\frac{8 (y^{2})}{{(1+x^{2}+y^{2})}^{3}}+\frac{2}{{(1+x^{2}+y^{2})}^{2}} \end{pmatrix}\]

Και η ορίζουσά της:

Det[hessian[x, y]]
\[-\frac{16 (x^{2})}{{(1+x^{2}+y^{2})}^{5}}-\frac{16 (y^{2})}{{(1+x^{2}+y^{2})}^{5}}+\frac{4}{{(1+x^{2}+y^{2})}^{4}}\]

Επίσης $\partial f(0,0)=$

fDx2[x_, y_] := Evaluate[D[f[x, y], {x, 2}]]
fDx2[x, y] /. systemD
{2}

Επίσης τιμή της ορίζουσας της εσσιανής στη θέση ισορροπίας είναι:

Det[hessian[x, y]] /. systemD
{4}

Επομένως έχουμε Ελάχιστο.

Σαγματικό σημείο

Clear["Global`*"]
fDx[x_, y_] := Evaluate[D[f[x, y], x]]
fDy[x_, y_] := Evaluate[D[f[x, y], y]]
f[x_, y_] := y^2 - x^2;
systemD = Solve[{fDx[x, y] == 0, fDy[x, y] == 0}, {x, y}];
Plot3D[f[x, y], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3 &} , 
 MeshStyle -> {Gray}, AxesLabel -> Automatic, ClippingStyle -> None, 
 ColorFunction -> "DarkRainbow", PlotRange -> All, PlotPoints -> 50]
3D Plot

Η Εσσιανή είναι:

hessian[x_, y_] := Evaluate[D[f[x, y], {{x, y}}, {{x, y}}]]
MatrixForm[hessian[x, y]]
\[\begin{pmatrix} -2 & 0 \\ 0 & 2 \end{pmatrix}\]

Και η ορίζουσά της:

Det[hessian[x, y]]
-4

Η τιμή της ορίζουσας της εσσιανής στη θέση ισορροπίας είναι:

Det[hessian[x, y]] /. systemD
{-4}

Επομένως έχουμε Σαγματικό Σημείο